<MST Extension> ::=

  <MST component conformance statement>
  <MST ATAP identification statement>
  <MST TBIC base statement>
{ <MST TBIC additional partition count statement>
  <MST TBIC additional partition list statement> }
  <MST ABM list statement>

<MST component conformance statement> ::=
  attribute MST_Component_Conformance of <component name> : entity is 
    <MST conformance string>;

<MST conformance string> ::= " <MST conformance identification> "

<MST conformance identification> ::= STD_1149_4_1999

<MST ATAP identification statement> ::=
  attribute MST_ATAP_AT1 of <component name> : entity is <port ID string>;
  attribute MST_ATAP_AT2 of <component name> : entity is <port ID string>;
{ attribute MST_ATAP_AT1N of <component name> : entity is <port ID string>;
  attribute MST_ATAP_AT2N of <component name> : entity is <port ID string>; }

<port ID string> ::= " <port ID> "

<MST TBIC base statement> ::=
  attribute MST_TBIC_Base of <component name> : entity is 
    <MST TBIC base string>

<MST TBIC base string> ::= " <MST TBIC base description> "

<MST TBIC base description> ::=
    <MST TBIC base D1 cell number>,
    <MST TBIC base D2 cell number>,
    <MST TBIC base Ca cell number>,
    <MST TBIC base Co cell number>
 {, <MST TBICN base D1 cell number>,
    <MST TBICN base D2 cell number>,
    <MST TBICN base Ca cell number>,
    <MST TBICN base Co cell number> }

<MST TBIC base D1 cell number> ::= <integer>
<MST TBIC base D2 cell number> ::= <integer>
<MST TBIC base Ca cell number> ::= <integer>
<MST TBIC base Co cell number> ::= <integer>
<MST TBICN base D1 cell number> ::= <integer>
<MST TBICN base D2 cell number> ::= <integer>
<MST TBICN base Ca cell number> ::= <integer>
<MST TBICN base Co cell number> ::= <integer>

<MST TBIC additional partition count statement> ::=
  attribute MST_TBIC_Add_Partition_Count of <component name> : entity is 
    <MST TBIC additional partition count string>;

<MST TBIC additional partition count string> ::=
  " <MST TBIC additional partition count> "

<MST TBIC additional partition count> ::= <integer>

<MST TBIC additional partition list statement> ::=
  attribute MST_TBIC_Add_Partition_List of <component name> : entity is 
    <MST TBIC additional partition list string>;

<MST TBIC additional partition list string> ::=
  " <MST TBIC additional partition list> "

<MST TBIC additional partition list> ::=
    <MST TBIC additional partition entry>
    {, <MST TBIC additional partition entry> }

<MST TBIC additional partition entry> ::=
    <MST TBIC additional partition number>
    ( <MST TBIC additional partition cells> )

<MST TBIC additional partition number> ::= <integer>
<MST TBIC additional partition cells> ::=
    <MST TBIC additional partition D1 cell number>,
    <MST TBIC additional partition D2 cell number>
 {, <MST TBICN additional partition D1 cell number>,
    <MST TBICN additional partition D2 cell number> }

<MST TBIC additional partition D1 cell number> ::= <integer>
<MST TBIC additional partition D2 cell number> ::= <integer>
<MST TBICN additional partition D1 cell number> ::= <integer>
<MST TBICN additional partition D2 cell number> ::= <integer>

<MST ABM list statement> ::=
  attribute MST_ABM_List of <component name> : entity is 
    <MST ABM list string>;

<MST ABM list string> ::= " <MST ABM list> "

<MST ABM list> ::= <MST ABM entry> {, <MST ABM entry> }

<MST ABM entry> ::= <port ID> ( <MST ABM description> )

<MST ABM description> ::=
    <MST TBIC partition number>,
    <MST ABM D cell number>,
    <MST ABM C cell number>,
    <MST ABM B1 cell number>,
    <MST ABM B2 cell number>

<MST TBIC partition number> ::= <integer>
<MST ABM D cell number> ::= <integer>
<MST ABM C cell number> ::= <integer>
<MST ABM B1 cell number> ::= <integer>
<MST ABM B2 cell number> ::= <integer>