Date: 18 Jul 97 18:13:44 -0700
Subject: New and Improved 1394 Copper Spice Model!
From: "Eric Hannah" <ehannah@mipos2.intel.com>
To: 'p1394@Sun.com'<p1394@Sun.COM>, 
        'p1394b@fireflyinc.com'<p1394b@fireflyinc.com>
X-Mailer: Cyberdog/2.0
MIMEEnabled: Y
MIME-Version: 1.0
Content-Type: multipart/mixed; boundary="Cyberdog-MixedBoundary-001E3E62"
Content-Transfer-Encoding: 7bit


--Cyberdog-MixedBoundary-001E3E62
Content-Type: text/enriched; charset=macintosh
Content-Transfer-Encoding: 8bit
X-Fontfamily: Monaco
X-Fontsize: 9

<SMALLER><SMALLER><FIXED>All,

	After reviewing the Tektronix generated Spice deck for the 1394 connector and reviewing our TDR data I decided that the parasitic elements inside the 1394-1995 connector could be much simplified. The differential mode connector is modeled as a single capacitor. The common mode connector is modeled as an L-C-L'  circuit. I also took on the challenge of building a Spice subcircuit that models both differential and common mode propagation through a lossy transmission line. The enclosed Spice deck models two connectors connected by 4.5 meters of multi-mode transmission line.


Methods:

	The differential mode connector model was hand tuned to replicate our differential TDR profile. Similarly for the common mode model. Only the first order, big impedances are modeled here. I used the standard Spice element for lossy transmission lines with the resistance/inch chosen to match the worst case cable loss in the IEEE Std 1394-1995 standard. Since frequency dependent losses aren't modeled the resistance factors were chosen for 200 MHz, which should handle the fundamental frequency for S400 signals.


Caveats:

* A fixed loss transmission line misses some important effects on the pulse shapes due to frequency dependencies

* Skew creates very high frequency common mode pulses but the current transmission line assumes 200 MHz signals

* This model has been tested for only a few days against TDR data and simple pulse trains

* There is no guarantee that the parasitic element values correspond to the true physics of the connectors


PHY Spice herders should be able to hack this subcircuit to fit different simulation needs. Let me hear about any problems or advantages to this model!


* SYNTAX IS FOR INTUSOFT'S IsSpice4 VERSION OF BERKELEY SPICE 3F.2

* TRANSMISSION MULTIPLE MODE MODELING DERIVED FROM:

* "ANALYSIS OF MUTLTICONDUCTOR TRANSMISSION LINES"

* BY CLAYTON R. PAUL (WILEY)

* IN PARTICULAR SEE P. 287


**************************************************************

.SUBCKT COPPER_CNT 1 2 3 4

* MODEL OF TWO 1394-1995 CONNECTORS + 4.5 METERS OF CABLE

* PINS 1 AND 2 ARE ONE SIDE, PINS 3 AND 4 ARE THE OTHER SIDE

* PINS 1 AND 3 ARE + DIFF VOLTAGE, PINS 2 AND 4 ARE - DIFF VOLTAGE

 

*	DEFINE AMMETERS:

VX1 1 5 DC 0VOLTS

VX2 2 6 DC 0VOLTS

VX3 3 7 DC 0VOLTS

VX4 4 8 DC 0VOLTS


*	DEFINE VOLTAGE GENERATORS FOR PINS:

BVPIN1 5 0 V=V(11)+V(9)/2

BVPIN2 6 0 V=V(11)-V(9)/2

BVPIN3 7 0 V=V(16)+V(10)/2

BVPIN4 8 0 V=V(16)-V(10)/2


*	DEFINE CURRENT SOURCES FOR THE TRANSMISSION LINES:

BIDIFF12 0 9 I=I(VX1)-I(VX2)

BIDIFF34 0 10 I=I(VX3)-I(VX4)

BICOM12 0 11 I=I(VX1)+I(VX2)

BICOM34 0 16 I=I(VX3)+I(VX4)


*	DEFINE DIFFERENTIAL MODE CONNECTORS+CABLE

* 		CONNECTOR: 1 INCH TRANS LINE + CAPACITOR:

.MODEL LOSSYDIFFSHORT LTRA R=0.99 G=0 L=13.56E-9 C=1.323E-12 LEN=1

ODIFF12 9 0 109 0 LOSSYDIFFSHORT

CCONN1 109 0 0.65PF


ODIFF34 10 0 110 0 LOSSYDIFFSHORT

CCONN2 110 0 0.65PF


*DIFF TRANSMISSION LINE

* 		MODEL FOR 4.5 METER DIFFERENTIAL MODE TRANSMISSION LINE:

* 		MODEL HAND TUNED AGAINST 5.8 DB LOSS AT 400 MHZ, BUT FIGURED FOR 200 MHZ

.MODEL LOSSYDIFF LTRA R=0.99 G=0 L=13.56E-9 C=1.323E-12 LEN=177

ODIFF 109 0 110 0 LOSSYDIFF


*	DEFINE COMMON MODE CONNECTORS+CABLE

* 		CONNECTOR: 1 INCH TRANS LINE + INDUCTOR-CAPACITOR-INDUCTOR:

.MODEL LOSSYCOMMONSHORT LTRA R=.30 G=0 L=4E-9 C=4.5E-12 LEN=1

OCOM12 11 0 111 0 LOSSYCOMMONSHORT

LCONN1 111 12 3.2NH

CCONN3 12 0 3PF

LCONN2 12 13 3NH


OCOM34 16 0 116 0 LOSSYCOMMONSHORT

LCONN3 15 116 3.2NH

CCONN4 15 0 3PF

LCONN4 14 15 3NH


*COMMON MODE TRANSMISSION LINE

* 		MODEL FOR 4.5 METER COMMON MODE TRANSMISSION LINE:

* 		MODEL HAND TUNED AGAINST 5.8 DB LOSS AT 400 MHZ, BUT FIGURED FOR 200 MHZ

.MODEL LOSSYCOMMON LTRA R=.30 G=0 L=4E-9 C=4.5E-12 LEN=177

OCOM 13 0 14 0 LOSSYCOMMON


.ENDS

**************************************************************



===========================

Eric Hannah, Intel Corporation

RN3-62, 2200 Mission College Blvd.

Santa Clara, CA 95052-8119

Phone: (408) 765-4441

Fax:     (408) 765-6271

Ehannah@mipos2.sc.intel.com

===========================


</FIXED></SMALLER></SMALLER>
--Cyberdog-MixedBoundary-001E3E62--